// searches 'src' and returns the number of times 'find' occurs in it
integer FindCount(string src, string find) {
    return llGetListLength(llParseStringKeepNulls(src, [find], [])) - 1;
}

// returns the index in 'src' where 'find' first occurs
// same as llSubStringIndex but slightly slower
integer Find(string src, string find) {
    list    split;
    
    split = llParseString2List(src, [find], []);
    if (llGetListLength(split) == 1) return -1; else return llStringLength(llList2String(split, 0));
}

// returns list of all positions in 'src' where 'find' occurs
list FindAll(string src, string find) {
    list    split;
    list    ret;
    integer i;
    integer pos;
    integer len;
    integer findlen = llStringLength(find);
    
    split = llParseStringKeepNulls(src, [find], []);
    len = llGetListLength(split) - 1;
    for (i = 0; i < len; i++) {
        pos += llStringLength(llList2String(split, i));
        ret += [pos];
        pos += findlen;
    }
    
    return ret;
}

// search 'src' and replace all occurences of 'find' with 'replace'
string ReplaceString(string src, string find, string replace) {
    return llDumpList2String(llParseStringKeepNulls(src, [find], []), replace);
}

default {
    state_entry() {
        string s = "xblablafoobarfoo";
        string search = "bla";
        llResetTime();
        llSay(0, "occurs " + (string)FindCount(s, search) + " times.");
        llSay(0, "1st position (Find): " + (string)Find(s, search));
        llSay(0, "all positions (FindAll): " + llList2CSV(FindAll(s, search)));
        llSay(0, ReplaceString(s, search, "monkey"));
        llSay(0, (string)llGetTime());
    }
}

string      SEPARATOR = "|%&|"; // for transmitting lists via linked messages

string List2TypeSep(list input) { // converts a list to a separated string with type information prepended to each item
    integer     i;
    list        output;

    for (i = 0; i < llGetListLength(input); i++) {
        output += [llGetListEntryType(input, i)] + llList2List(input, i, i);
    }
    
    return llDumpList2String(output, SEPARATOR);
}

list TypeSep2List(string inputstring) { // converts a separated string created with List2TypeSep back to a list with the correct type information
    integer     i;
    list        input;
    list        output;
    
    input = llParseString2List(inputstring, [SEPARATOR], []);

    for (i = 0; i < llGetListLength(input); i += 2) {
        if (llList2Integer(input, i) == TYPE_INTEGER) output += (integer)llList2String(input, i + 1);
        else if (llList2Integer(input, i) == TYPE_FLOAT) output += (float)llList2String(input, i + 1);
        else if (llList2Integer(input, i) == TYPE_STRING) output += llList2String(input, i + 1);
        else if (llList2Integer(input, i) == TYPE_KEY) output += (key)llList2String(input, i + 1);
        else if (llList2Integer(input, i) == TYPE_VECTOR) output += (vector)llList2String(input, i + 1);
        else if (llList2Integer(input, i) == TYPE_ROTATION) output += (rotation)llList2String(input, i + 1);
    }
    
    return output;
}

string Bool2String(integer bool) { // returns TRUE or FALSE as string
    if (bool) return("TRUE"); else return("FALSE");
}

integer String2Bool(string str) { // returns TRUE or FALSE based on string
    list        positive = ["y", "yes", "t", "true", "on", "1"];
    
    if (llListFindList(positive, [llToLower(str)]) == -1) return FALSE; else return TRUE;
}

integer IsKey(string str) { // returns TRUE if string is a key
    return ( (llStringLength(str) == 36) &&
        (llGetSubString(str, 8, 8) == "-") &&
        (llGetSubString(str, 13, 13) == "-") &&
        (llGetSubString(str, 18, 18) == "-") &&
        (llGetSubString(str, 23, 23) == "-") );
}

// return <number> as string with zero-padding on the left so it's <length> characters
string PadLeft(integer number, integer length) {
    return  llDeleteSubString("0000000000", length, llStringLength((string)number) - 1) + (string)number;
}

// return the input <number> as string with <point> decimals
string float2stringcut(float number, integer point) {
    return llGetSubString((string)number, 0, llSubStringIndex((string)number, ".") + point);
}